;; BLOCKEDIT.LSP  Copyright 1996, 1997 Tony Tanzillo
;; 
;; WEB:   http://ourworld.compuserve.com/homepages/tonyt
;; EMAIL: tony.tanzillo@worldnet.att.net
;; --------------------------------------------
;; 
;; BLOCKEDIT Command (Windows 95/NT only).
;; 
;; This program originally appeared in an article
;; by the author, which was published in AutoCAD 
;; Tech Journal.
;; 
;; Updated for AutoCAD Release 14
;;
;; Automates editing of blocks and external
;; references in an open drawing using a 
;; second instance of AutoCAD.  
;; 
;; >>>> IMPORTANT:
;; 
;; This program requires a new entry to be added 
;; to your ACAD.PGP file, located in your support 
;; directory. See below for the required changes.
;; 
;; Normally, to edit the definition of a block
;; in a second instance of AutoCAD, you must
;; WBLOCK, open the resulting file in a second
;; instance of AutoCAD, edit it there, save it
;; and then reinsert it into the source drawing.
;; 
;; BLOCKEDIT completely automates all of these
;; steps except the editing itself. Just enter
;; the name of a block or external reference
;; (or press return and select an insertion of
;; it), and BLOCKEDIT opens the block definition
;; or external reference drawing in a second
;; instance of AutoCAD, where you can edit it.
;; 
;; When you are finished editing the block or
;; XREF in the second instance, just save your
;; changes and exit that copy of AutoCAD, and 
;; the modified block/xref will automatically be 
;; updated in the source drawing.
;; 
;; To use this routine, load it and then enter
;; BLOCKEDIT on the command line. You can enter
;; the name of the block to be edited, or you
;; can press return and pick an insertion of it.
;;
;; Once you select the block, a second AutoCAD
;; session will be started which contains the
;; block's definition.  Edit the block, then
;; END the editing session with the block, and
;; the block definition in the primary editing
;; session will be updated automatically.
;; 
;; >>>>>>>>>>>>>>>> IMPORTANT <<<<<<<<<<<<<<<<<
;; ============================================
;; 
;; This program requires the following external
;; command entry to be added to ACAD.PGP:
;; 
;; SHELLOPEN, START /W, 4,*File to open: ,
;; 

(defun getblk (msg / name e d)
   (setq name
      (getstring (strcat msg "/<select>: ")))
   (cond
      (  (eq name "")
         (setq e (car (entsel
            "\nSelect insertion: " )))
         (cond
            (  (not e) nil)
            (  (/= "INSERT" 
                    (cdr (assoc 0 (setq d (entget e)))))
               (princ "\nSelected object is not a block.")
               nil
            )
            (t (cdr (assoc 2 d)))
         )
      )
      (  (not (setq b (tblsearch "block" name)))
         (princ (strcat "\nBlock " name
             " not defined in this drawing.")) nil)
      (t (strcase name))
   )
)

(defun tempname (file ext)
   (strcat (getvar "tempprefix") file "." ext)
)

(defun && (a b)
   (not (zerop (logand a b)))
)

(defun blockflags (b)
   (  (lambda (d)
         (if d (cdr (assoc 70 d)))
      )
      (tblsearch "block" b)
   )
)

(defun xrefpath (b / p)
   (  (lambda (d)
         (if d (setq p (cdr (assoc 1 d))))
      )
      (tblsearch "block" b)
   )
   (if p (findfile p))
)

(defun quotes (s)
   (strcat (chr 34) s (chr 34))
)

(defun C:BLOCKEDIT ( / blk flags xref?)
   (cond
      (  (not (setq blk (getblk "Block to edit"))))
      (  (not (setq flags (blockflags blk))))
      (  (&& 1 flags)
         (princ "\nCan't edit anonymous blocks."))
      (  (&& 16 flags)
         (princ "\nCan't edit externally-dependent blocks."))
      (  (and (setq xref? (&& 4 flags))
              (not (&& 32 flags)))
         (princ "\nSpecified external reference is unresolved."))
      (t (setvar "CMDECHO" (if *debug* 1 0))
         (if (not xref?)
             (blockedit blk)
             (xrefedit blk)
         )
      )
   )
   (princ)
)

(defun dwgedit (file)
   (command "._SHELLOPEN"
      (strcat 
         (quotes (findfile "acad.exe")) 
         " " 
         (quotes file)

      )
   )
)

(defun blockedit (blk / blktemp)
   (setq blktemp (tempname "$block$" "dwg"))
   (command "._wblock" blktemp)
   (if (and (findfile blktemp)
            (> 2 (getvar "expert")))
       (command "_Y")
   )
   (princ 
      (strcat 
         "\nOpening block " blk " in new drawing editor,"
         "\nClose other drawing editor to continue."
      )
   )
   (command blk)
   (dwgedit blktemp)
   (command blk 
      "._INSERT" (strcat blk "=" blktemp)
   )
   (command)
   (princ (strcat "\nBlock " blk " updated."))
)

(defun xrefedit (blk / xrefname)
   (setq xrefname (xrefpath blk))
   (princ 
      (strcat 
         "\nOpening external reference " blk " in new drawing editor,"
         "\nClose other drawing editor to continue."
      )
   )
   (command "._XREF" "_Unload" blk)
   (dwgedit xrefname)
   (command "._XREF" "_Reload" blk)
   (princ (strcat "\nExternal reference " blk " updated."))
)

(princ "\nBLOCKEDIT command loaded.")
(princ)

;; ======================== EOF BLOCKED.LSP ===========================